分支

if 表达式将过程分为两个部分。格式如下：

(if predicate then-value else-value)

如果 predicate 部分为 真 ，那么 then-value 部分 被求值 ，否则 else-value 部分被 求值 ，并且 求得的值 会 返回 给 if语句的括号外

true 是除 false 以外的任意值：

• true 使用 #t 表示
• false 用 #f 表示

    在R5RS中，false #f 和空表 '() 是两个不同的对象

    然而，在MIT-Scheme中，这两个为同一对象

    这个不同可能是历史遗留问题，在以前的标准R4RS中，#f 和 '() 被定义为同一对象

从兼容性角度考虑， 不应该使用表目录作为谓词 。使用函数 null? 来判断 表是否为空

(null? '()) ; #t 

(null? '(a b c)) ; #f 

if 表达式是一个 特殊形式 ，因为它 不对所有的参数求值

• 如果 predicate 为真，则只有 then-value 部分被求值
• 如果 predicate 为假，只有 else-value 部分被求值

例，首项为 a0，增长率 r，项数为 n 的几何增长数列之和：

(define (sum-gp a0 r n)
  (* a0
     (if (= r 1)
         n
         (/ (- 1 (expt r n)) (- 1 r)))))   ; !!

通常来说，几何增长数列的求和公式如下：

a0 * (1 - r^n) / (1 - r)                      (r ≠ 1)
a0 * n                                               (r = 1)

如果 if 表达式对所有参数求值的话，那么有 ;!! 注释的那行就算在 r = 1 时也会被求值，这将导致产生一个 除数为0 的错误

可以省去 else-value 项。当 predicate 为假时， 返回值就没有被指定 。如果你希望当predicate为假时返回 #f ，那么就要明确地将它写出来

then-value 和 else-value 都应该是 S-表达式

如果你需要副作用 ，那么就应该使用 begin 表达式

    尽管所有的分支都可以用 if表达式 表达

    但当条件有更多的可能性时，就需要使用嵌套的if表达式了，这将使代码变得复杂

处理这种情况可以使用 cond表达式 。cond表达式的格式如下：

(cond
  (predicate-1 clauses-1)
  (predicate-2 clauses-2)
    ......
  (predicate-n clauses-n)
  (else        clauses-else))

在 cond表达式 中， predicates-i 是按照 从上到下 的顺序求值：

• 当 predicates-i 为 真 时， clause-i 会被 求值并返回
• i 之后的 predicates 和 clauses 不会被求值
• 如果所有的 predicates-i 都是 假 的话，则返回 cluase-else

在一个子句中，可以写数条S-表达式，而 clause 的值是 最后一条 S-表达式

例：城市游泳池的收费。

Foo市的城市游泳池按照顾客的年龄收费：

如果 age ≤ 3 或者 age ≥ 65 则 免费；
如果 介于 4 ≤ age ≤ 6 则 0.5美元；
如果 介于 7 ≤ age ≤ 12 则 1.0美元；
如果 介于 13 ≤ age ≤ 15 则 1.5美元；
如果 介于 16 ≤ age ≤ 18 则 1.8美元；
其它 则 2.0美元；

那么，一个返回城市游泳池收费的函数如下：

(define (fee age)
  (cond
   ((or (<= age 3) (>= age 65)) 0)
   ((<= 4 age 6) 0.5)
   ((<= 7 age 12) 1.0)
   ((<= 13 age 15) 1.5)
   ((<= 16 age 18) 1.8)
   (else 2.0)))

这里将介绍一些用于做判断的函数。这些函数的名字都以 '?' 结尾